( **********************************************************************
  File:        ETSIPRI2.F
  Author:      Dencom Inc.     -     www.dencom-inc.com
  Date:        March 20, 1998
  Description: This file contains commands used to build ies and messages.
  ********************************************************************** )


( **********     Build Information Elements     ********** )


: BUILD_CHANNEL_ID         ( -- )
   I#CHANNEL_ID ELEMENT>
       ALL_INCLUDED
       #EXPLICIT               *COD ->CID_INT_PRESENT          !
       #OTHER_INTERFACE        *COD ->CID_INT_TYPE             !
       #EXCLUSIVE              *COD ->CID_PREF/EXCL            !
       #NOT_D_CHANNEL          *COD ->CID_DCHANNEL             !
       #AS_INDICATED           *COD ->CID_INFO_CHAN_SEL        !
       X" 00"                  *COD ->CID_INT_ID               !STRING
       #CCITT                  *COD ->CID_CODING_STANDARD      !
       #NUMBER                 *COD ->CID_NUMBER/MAP           !
       #B_CHANNEL_UNITS        *COD ->CID_CHANNEL/MAP_TYPE     !
       CHANNEL-NUMBER @        *COD ->CID_NUMBER               !
   <ELEMENT
;

: BUILD_BEARER_CAP         ( -- )
   I#BEARER_CAP ELEMENT>
       ALL_EXCLUDED
       OCTET_3 INCLUDED
       OCTET_4 INCLUDED
       OCTET_4A INCLUDED
       OCTET_4B INCLUDED
       #CCITT                  *COD ->BC_CODING_STANDARD       !
       #SPEECH                 *COD ->BC_TRANSFER_CAP          !
       #CIRCUIT_MODE           *COD ->BC_TRANSFER_MODE         !
       #64KBIT/S               *COD ->BC_TRANSFER_RATE         !
       #DEFAULT                *COD ->BC_STRUCTURE             !
       #POINT_TO_POINT         *COD ->BC_CONFIGURATION         !
       #DEMAND                 *COD ->BC_ESTABLISHMENT         !
       #BIDIRECT_SYMMETRIC     *COD ->BC_SYMMETRY              !
       #64KBIT/S               *COD ->BC_TRANSFER_RATE_4B      !
   <ELEMENT
;

: BUILD_CALLED_NUM         ( -- )
   I#CALLED_NUM ELEMENT>
       ALL_INCLUDED
       #UNKNOWN                *COD ->CLDN_NUMBER_TYPE         !
       #ISDN_PLAN              *COD ->CLDN_NUMBERING_PLAN      !
       CALLED-NUMBER           *COD ->CLDN_NUMBER              !STRING
   <ELEMENT
;

: BUILD_CALLING_NUM        ( -- )
   I#CALLING_NUM ELEMENT>
       ALL_INCLUDED
       #UNKNOWN                *COD ->CLGN_NUMBER_TYPE         !
       #ISDN_PLAN              *COD ->CLGN_NUMBERING_PLAN      !
       #PRESENT_ALLOWED        *COD ->CLGN_PRESENTATION        !
       #NETWORK_PROVIDED       *COD ->CLGN_SCREENING           !
       CALLING-NUMBER          *COD ->CLGN_NUMBER              !STRING
   <ELEMENT
;

: BUILD_CAUSE              ( CAUSE-VALUE -- )
   I#CAUSE ELEMENT>
       ALL_EXCLUDED
       OCTET_3 INCLUDED
       OCTET_4 INCLUDED
       #CCITT                  *COD ->C_CODING_STANDARD        !
       #USER                   *COD ->C_LOCATION               !
       ( CAUSE-VALUE )         *COD ->C_CAUSE_VALUE            !
   <ELEMENT
;

: BUILD_RESTART_INDICATOR  ( -- )
   I#RESTART_IND ELEMENT>
       ALL_EXCLUDED
       OCTET_3 INCLUDED
       #INDICATED_CHANNEL      *COD ->RI_CLASS                !
   <ELEMENT
;


( **********     Build and send SETUP message     ********** )


: SEND_SETUP               ( -- )
   2           =CR_LENGTH
   CR-VALUE @  =CN_CR_VALUE
   #ORIG       =CN_CR_FLAG

   BUILD_CHANNEL_ID
   BUILD_CALLING_NUM
   BUILD_CALLED_NUM
   BUILD_BEARER_CAP

   M#SETUP MESSAGE>
       I#BEARER_CAP
       CHANNEL-NUMBER @
       IF
           I#CHANNEL_ID
       ENDIF
       CALLING-NUMBER @
       IF
           I#CALLING_NUM
       ENDIF
       CALLED-NUMBER @
       IF
           I#CALLED_NUM
       ENDIF
   <SEND
;

: LOAD_SETUP               ( -- )
   T1? @
   IF
       24 1
       DO
           INCR_CALLED_NUMBER
           INCR_CALLING_NUMBER
           I CR-VALUE !
           I CHANNEL-NUMBER !
           SEND_SETUP
       LOOP
   ELSE
       31 1
       DO
           INCR_CALLED_NUMBER
           INCR_CALLING_NUMBER
           I CR-VALUE !
           I 16 <
           IF
               I CHANNEL-NUMBER !
           ELSE
               I 1 + CHANNEL-NUMBER !
           ENDIF
           SEND_SETUP
       LOOP
   ENDIF
;


( **********     Build and send CALL PROC message     ********** )


: SEND_CALL_PROC           ( -- )
   EXTRACT_CR_VALUE
   BUILD_CHANNEL_ID
   M#CALL_PROC MESSAGE>
       CHANNEL-NUMBER @
       IF
           I#CHANNEL_ID
       ENDIF
   <SEND
;


( **********     Build and send ALERT message     ********** )


: SEND_ALERT               ( -- )
   EXTRACT_CR_VALUE
   M#ALERT MESSAGE>
   <SEND
;


( **********     Build and send CONNECT message     ********** )


: SEND_CONN                ( -- )
   EXTRACT_CR_VALUE
   M#CONN MESSAGE>
   <SEND
;


( **********     Build and send CONNECT_ACK message     ********** )


: SEND_CONN_ACK            ( -- )
   EXTRACT_CR_VALUE
   M#CONN_ACK MESSAGE>
   <SEND
;


( **********     Build and send DISC message     ********** )


: SEND_DISC                ( CAUSE-VALUE -- )
   2           =CR_LENGTH
   CR-VALUE @  =CN_CR_VALUE
   CR-FLAG @   =CN_CR_FLAG

   BUILD_CAUSE
   M#DISC MESSAGE>
       I#CAUSE
   <SEND
;

: LOAD_TEARDOWN            ( -- )
   T1?
   IF
       24 1
   ELSE
       31 1
   ENDIF
   DO
       I CR-VALUE !
       #ORIG CR-FLAG !
       #NORMAL_CLEARING
       SEND_DISC
   LOOP
;


( **********     Build and send REL message     ********** )


: SEND_REL                 ( -- )
   EXTRACT_CR_VALUE
   M#REL MESSAGE>
   <SEND
;


( **********     Build and send REL_COM message     ********** )


: SEND_REL_COM             ( -- )
   EXTRACT_CR_VALUE
   M#REL_COM MESSAGE>
   <SEND
;


( **********     Build and send RESTART message     ********** )


: SEND_RESTART             ( -- )
   EXTRACT_CR_VALUE
   BUILD_RESTART_INDICATOR
   M#REST MESSAGE>
       I#RESTART_IND
   <SEND
;


( **********     Build and send RESTART ACK message     ********** )


: SEND_RESTART_ACK         ( -- )
   EXTRACT_CR_VALUE
   BUILD_RESTART_INDICATOR
   M#REST_ACK MESSAGE>
       I#RESTART_IND
   <SEND
;